Page MenuHomeFreeBSD
Files F108569256

D45623.diff
No OneTemporary
Actions

D45623.diff
View Options

diff --git a/lib/libc/aarch64/string/Makefile.inc b/lib/libc/aarch64/string/Makefile.inc
--- a/lib/libc/aarch64/string/Makefile.inc
+++ b/lib/libc/aarch64/string/Makefile.inc
@@ -14,7 +14,6 @@
strchr \
strchrnul \
strcpy \
- strlen \
strnlen \
strrchr
@@ -30,7 +29,8 @@
strncmp.S \
memccpy.S \
strncat.c \
- strlcat.c
+ strlcat.c \
+ strlen.S
#
# Add the above functions. Generate an asm file that includes the needed
diff --git a/lib/libc/aarch64/string/strlen.S b/lib/libc/aarch64/string/strlen.S
new file mode 100644
--- /dev/null
+++ b/lib/libc/aarch64/string/strlen.S
@@ -0,0 +1,46 @@
+/*-
+ * SPDX-License-Identifier: BSD-2-Clause
+ *
+ * Copyright (c) 2024 Getz Mikalsen <getz@FreeBSD.org>
+*/
+
+#include <machine/asm.h>
+
+ .weak strlen
+ .set strlen, __strlen
+ .text
+
+ENTRY(__strlen)
+ bic x10, x0, #0xf // aligned src
+ and x9, x0, #0xf
+ ldr q0, [x10]
+ cmeq v0.16b, v0.16b, #0
+ shrn v0.8b, v0.8h, #4
+ fmov x1, d0
+ cbz x9, .Laligned
+ lsl x2, x0, #2 // get the byte offset
+ lsr x1, x1, x2 // shift by offset index
+ cbz x1, .Lloop
+ rbit x1, x1
+ clz x0, x1
+ lsr x0, x0, #2
+ ret
+
+.Laligned:
+ cbnz x1, .Ldone
+
+.Lloop:
+ ldr q0, [x10, #16]!
+ cmeq v0.16b, v0.16b, #0
+ shrn v0.8b, v0.8h, #4 // reduce to fit mask in GPR
+ fcmp d0, #0.0
+ b.eq .Lloop
+ fmov x1, d0
+.Ldone:
+ sub x0, x10, x0
+ rbit x1, x1 // reverse bits as NEON has no ctz
+ clz x3, x1
+ lsr x3, x3, #2
+ add x0, x0, x3
+ ret
+END(__strlen)

File Metadata

Mime Type
text/plain
Expires
Mon, Jan 27, 11:16 AM (4 h, 11 m)
Storage Engine
blob
Storage Format
Raw Data
Storage Handle
16154525
Default Alt Text
D45623.diff (1 KB)

Event Timeline